Godot4で作るローグライク-03-ダンジョンシーンの作成その２（ダンジョン生成とダンジョンマップ）

func create_rooms():
# 部屋を生成する。一応穴掘り法？で掘っていく

#	var pos : Vector2
	var currentroom = []
	var nextroom = []

	# 最初の部屋を取得
	currentroom = _create_startroom()

	# 隣接するマスに部屋を作成する
	var tmproomnum = 0		# 部屋生成カウンタ
	if _rooms.size() == 1:
		tmproomnum = 1		# さきに始点の部屋作ってたら１から始める

	while _rooms.size() < _roomnum:

		# 次の部屋を取得する
		nextroom = _create_next_room(currentroom)

		if nextroom.size() < 1:
			# 次の部屋が作成できなかったら
			# スタート地点を変えて掘りなおす
			tmproomnum = 999
		else:
			# 次の部屋が出来たら
			# 部屋と部屋をつなぐ設定をする
			_connect_rooms(currentroom, nextroom)
			
			# その部屋から次を掘る
			currentroom = nextroom
			tmproomnum += 1

		# 連続で一定数部屋を生成したら
		# 既にある部屋からランダムに選んで、そこからまた部屋を生成する
		if tmproomnum >= _roomnum:
			# ランダムに生成された部屋を取得する
			currentroom = _rooms[randi()%_rooms.size()]

	# 部屋の生成が終了したら、スタート地点とゴール地点を設定
	# スタートは最初に作成した部屋に設定
	_rooms[0].type = Gamesettings.RoomType.Start
	# 現在地をスタート地点に設定
	_current_room_pos = _rooms[0].pos
	# スタート地点の来たことあるフラグを立てる
	_rooms[0].visited = true
	# ゴールはスタート以外の部屋にランダムに設定
	_rooms[randi()%(_rooms.size()-1)+1].type = Gamesettings.RoomType.Goal
	# 部屋内のオブジェクトを生成する
	for room in _rooms:
		room.objects = _set_obj_room(room)

func _create_startroom():
# 掘り始めるマスを決める
# 部屋が一つもない場合は、ランダムに部屋を作成し返す
# 既に部屋がある場合は、既存の部屋からランダムに選択し返す

	var index = 0
	# 部屋が1つも存在しなかったら、ランダムにマスを選択する
	if _rooms.size() < 1:
		_add_room(Vector2(randi()%_width, randi()%_height), Gamesettings.RoomType.Others)
		return _rooms[0]
	else:
		index = randi()%_rooms.size()
		return _rooms[index]

func _add_room(pos:Vector2, type:Gamesettings.RoomType):
# 部屋情報を追加する

	var room = {
		"pos" : pos,				# 部屋の座標
		"exits" : [],				# 隣の部屋につながっている出口、２次元配列になっている
									# 出口がある方向（上下左右の壁）とつながっている部屋の座標を格納
									# 壁４つ分設定（出口がある壁の情報のみ登録される）
		"type" : type,				# いまのところはスタート、ゴール、その他のみ
		"visited" : false,			# この部屋に訪れたことがあるか？
		"objects" : []				# 部屋内のオブジェクトを設定
	}
	_rooms.append(room)

func _create_next_room(room):
# 指定された部屋から次の部屋を生成
# 移動できる部屋が複数あれば、ランダムで1つのマスを選び部屋を生成する
# 生成した部屋を返す
# 移動先が無い場合は空を返す

	var nextpos : Vector2
	var tmptiles = []		# 作成可能な部屋を格納する（全部）
	for i in range(4):
		nextpos = room.pos + DIRLIST[i]
		if is_tile_open(nextpos):
			# マスが空いていたら記録する
			tmptiles.append(nextpos)

	if tmptiles.size() == 0:
		# 空いているマスが無ければ空を返す
		return []
	else:
		# 空いていたら、その中からランダムで選択したマスに部屋を作り返す
		nextpos = tmptiles[randi()%tmptiles.size()]
		_add_room(nextpos, Gamesettings.RoomType.Others)
		# 最後に追加した部屋を返す
		return _rooms[_rooms.size() - 1]

func _connect_rooms(room1, room2):
# 隣り合っている二つの部屋がつながっているという情報をそれぞれの部屋に設定する

	if room1.pos == room2.pos - DIRLIST[Gamesettings.Direction.LEFT]:
		# １が左側２が右側
		room1.exits.append({"direction" : Gamesettings.Direction.LEFT, "pos" : room2.pos})
		room2.exits.append({"direction" : Gamesettings.Direction.RIGHT, "pos" : room1.pos})
	elif room1.pos == room2.pos - DIRLIST[Gamesettings.Direction.UP]:
		# １が上側２が下側
		room1.exits.append({"direction" : Gamesettings.Direction.UP, "pos" : room2.pos})
		room2.exits.append({"direction" : Gamesettings.Direction.DOWN, "pos" : room1.pos})
	elif room1.pos == room2.pos - DIRLIST[Gamesettings.Direction.RIGHT]:
		# １が右側２が左側
		room1.exits.append({"direction" : Gamesettings.Direction.RIGHT, "pos" : room2.pos})
		room2.exits.append({"direction" : Gamesettings.Direction.LEFT, "pos" : room1.pos})
	elif room1.pos == room2.pos - DIRLIST[Gamesettings.Direction.DOWN]:
		# １が下側２が上側
		room1.exits.append({"direction" : Gamesettings.Direction.DOWN, "pos" : room2.pos})
		room2.exits.append({"direction" : Gamesettings.Direction.UP, "pos" : room1.pos})

func _set_obj_room(room):
# 生成した部屋の中にオブジェクトを設置する
# 今のところは壁のみ
# ２次元配列を返す
	var room2d = []
	# 部屋と壁を作成
	for i in range(Gamesettings.ROOM_HEIGHT):
		var tmp = []
		for j in range(Gamesettings.ROOM_WIDTH):
			if i == 0 or i == Gamesettings.ROOM_HEIGHT - 1:
				tmp.append(Gamesettings.RoomObj.WALL)
			elif j == 0 or j == Gamesettings.ROOM_WIDTH - 1:
				tmp.append(Gamesettings.RoomObj.WALL)
			else:
				tmp.append(Gamesettings.RoomObj.NON)
		room2d.append(tmp)

	# 出口を作成する
	for exit in room.exits:
		if exit.direction == Gamesettings.Direction.LEFT:
			room2d[4][0] = exit.direction + 2
		elif exit.direction == Gamesettings.Direction.UP:
			room2d[0][5] = exit.direction + 2
		elif exit.direction == Gamesettings.Direction.RIGHT:
			room2d[4][10] = exit.direction + 2
		elif exit.direction == Gamesettings.Direction.DOWN:
			room2d[8][5] = exit.direction + 2

	return room2d

extends Node2D
## タイルレイヤー.
enum eTileLayer {
	BACKGROUND ,	# 背景レイヤー
	ROOMS,			# 部屋レイヤー
	EXIT,			# 出口用のタイル（複数出口があるときは重ねる）
	OBJECT = 6		# マップに表示するオブジェクト（今のところはスタートとゴールのみ）
}
const NONEXIT = Vector2(1, 0)
const DIRTILELIST = [
	Vector2(0, 1),		# 左向きタイル
	Vector2(1, 1),		# 上向きタイル
	Vector2(2, 1),		# 右向きタイル
	Vector2(3, 1),		# 下向きタイル
	Vector2(0, 2),		# スタート
	Vector2(1, 2)		# ゴール
]


@onready var tilemap = $TileMap

func proc(mapdata:Array) -> void:
# 1階層のマップを表示する

	for room in mapdata:
		# 来たことあるフラグが立っている部屋だけ表示する
		if room.visited:
			# 出口が無いタイル（無くてもいい）
			tilemap.set_cell(eTileLayer.ROOMS, room.pos, 0, NONEXIT)
			# 出口付きのタイルを貼る
			var exitnum = 0
			for exit in room.exits:
				tilemap.set_cell(eTileLayer.EXIT + exitnum, room.pos, 0, DIRTILELIST[exit.direction])
				exitnum += 1
			# スタート地点とゴール地点もマップに表示
			if room.type == Gamesettings.RoomType.Start:
				tilemap.set_cell(eTileLayer.OBJECT, room.pos, 0, DIRTILELIST[4])
			elif room.type == Gamesettings.RoomType.Goal:
				tilemap.set_cell(eTileLayer.OBJECT, room.pos, 0, DIRTILELIST[5])

extends Node2D


func dsp_pin(pos):
# マップにピンを表示する（座標を変えるだけ）
# 最後の＋はdungeon_mapの座標

	position.x = (pos.x * Gamesettings.TILE_SIZE) + 180
	position.y = (pos.y * Gamesettings.TILE_SIZE) + 0